home *** CD-ROM | disk | FTP | other *** search
/ Gamers Delight 2 / Gamers Delight 2.iso / Aminet / game / think / MADgic41.lzh / 1988 / cowboy.s < prev    next >
Text File  |  1989-10-04  |  3KB  |  81 lines
  1. ;Cowboy
  2. ;by Eugene P. Lilitko
  3. ;Union of Soviet Socialist Republics
  4. ;
  5. ;The snare for the opponent's processes.
  6. ;Bison commits suicide when all 64 processes are captured.
  7. ;
  8. FIRE          DAT                    FIRE
  9. ; 
  10. BEG           DAT                    BEG
  11. FENCE         MOV      SUCCESS,       SWITCH
  12. DEMON         SUB   #  1,             BISON
  13. HELP          SPL                    DEMON
  14. BOMBING       MOV      FIRE,       <  FIRE
  15.               JMN      HELP,          BISON
  16.               MOV      BOMB,          HELP
  17. BOMB          DAT                    BOMB
  18. BISON         DAT                    64
  19. COUNT         JMP      FENCE
  20. ; 
  21. ;Welcome to the snare!
  22. ;
  23. WELLC1        JMP   <  WELLC1
  24. WELLC2        JMP   @  WELLC2
  25. ; 
  26. ; 
  27. ;The main code.  Traps are set, inviting the opponent to jump
  28. ;into the snare.  When the bison are captured, SWITCH is changed
  29. ;to the instructions of SUCCESS.
  30. ;
  31. START         MOV      REST,          SWITCH
  32. GBOMB         MOV   #  575,           FIRECNT
  33.               MOV   #  64,            BISON
  34.               SPL                    RADAR
  35. CONT          MOV   #  4098,          WELLC1
  36.               MOV   # -4099,          WELLC2
  37. LOOP          MOV      WELLC1,     @  WELLC2
  38.               MOV      WELLC2,     @  WELLC1
  39.               ADD   #  7,             WELLC1
  40.               SUB   #  7,             WELLC2
  41. SWITCH        DJN      LOOP,          FIRECNT
  42. ; 
  43. ;All right! There are bison in the snare.  The captured bison invite free
  44. ;bison into the trap.  Cowboy must help them!
  45. ;
  46. NEW           MOV      BOMB,          FIRE
  47.               MOV      BOMB,          KILL
  48. SHOOT         MOV      FIRE,       <  FIRE
  49.               JMZ      SHOOT,         KILL
  50. FORWARD       JMP      NEW
  51. SUCCESS       MOV      GBOMB,         SUCCESS
  52. REST          DJN      SHOOT,         COPY+3
  53. ; 
  54. ;The defense process.  Build a set of pickets, test for a breach of the
  55. ;pickets, and switch to defensive action when the pickets are breached.
  56. ;Defense occurs when Cowboy is copied to a new place in memory, and the
  57. ;copy begins operating properly.
  58. ;
  59. RADAR         MOV   #  638,           FORWARD
  60.               MOV   # -638,           BACK
  61.               MOV   #  25,            COUNT
  62. MAKE          MOV      COUNT,      <  FORWARD
  63.               MOV      COUNT,      <  BACK
  64.               DJN      MAKE,          COUNT
  65. TEST          MOV   #  638,           FORWARD
  66.               MOV   # -638,           BACK
  67.               MOV   #  25,            COUNT
  68. COMPARE       CMP   <  FORWARD,    <  BACK
  69. BACK          JMP      ALARM
  70. KILL          DJN      COMPARE,       COUNT
  71. FIRECNT       JMP      TEST
  72. ALARM         MOV      BOMB,          SWITCH
  73.               MOV   #  50,            BEG
  74.               MOV   #  3310,          FORWARD
  75. COPY          MOV   @  BEG,        <  FORWARD
  76.               DJN      COPY,          BEG
  77.               MOV      NEW,           BOMBING
  78.               ADD   #  11,            FORWARD
  79. ; 
  80. FINISH        JMP   @  FORWARD
  81.               END      START